ArcGIS Pro silent install script (1.0 - 1.2)

Document created by curtvprice Champion on Jan 30, 2015Last modified by curtvprice Champion on Nov 2, 2016
Version 8Show Document
  • View in full screen mode

This is in good old DOS batch language. I have tested it with 1.0 - 1.2. So far, pro updates don't require an uninstall, so you can just rerun it with a new version. In theory, this script could be used to create an SCCM package for automated deployment to many desktops.

 

See the commented out code to include the 1.1.1 update in a 1.1 install.

Also, see: ArcGIS Pro silent install script (1.3 and later)

 

:: install_arcgispro.bat
:: Silent install of ArcGIS Pro
::
:: INSTRUCTIONS:
:: 1) Edit this script as instructed below in the comments
:: 2) Save with ".bat" extension
:: 3) Open an administrative command window.
:: 4) Run this install script from the command line
::    Alternatively, deployment software can be used to run the script.
::
:: Required files:
:: \---Esri
::     +--ArcGISPro
::          ArcGISPro.cab
::          ArcGISPro.msi
::     +--ArcGISProHelp
::          ArcGISProHelp.cab
::          ArcGISProHelp.msi     
::     +--ArcGISProPython
::          Python34.cab
::          Python34.msi
::
:: References:
:: * ArcGIS 10.3 Enterprise Deployment
::  
http://support.esri.com/en/knowledgebase/whitepapers/view/productid/160/metaid/2145

:: * ArcGIS Pro installation guide:
::   .\Esri\ArcGISPro\Documentation\install.htm
::
:: Author: Curtis Price,
cprice@usgs.gov

::
:: History:
:: 01/30/2015 ArcGIS Pro 1.0 - Initial release
:: 08/19/2015 Added .NET 4.5 check
::----------------------------------------------------------------
:: This software is provisional and subject to revision; it has
:: not been thoroughly reviewed or received USGS final approval.
:: Users are cautioned to consider carefully the provisional
:: nature of the code before using it for decisions that concern
:: personal or public safety or the conduct of business that
:: involves substantial monetary or operational consequences.
@echo off


:: %~d0%~p0 is folder where this script resides
set SRC=%~d0%~p0
set LOGDIR=%TEMP%
set INSTALLDIR=C:\ArcGIS\Pro

:: ====================================================================
::                PLEASE DO NOT EDIT BELOW THIS LINE
:: ====================================================================

:: Check for .NET 4.5
set x64key=HKLM\SOFTWARE\Microsoft\.NETFramework
%WINDIR%\system32\reg.exe query %x64key%  /f ".NETFramework,Version=v4.5.1" /k /s >NUL ^
  || ( echo. & echo ** Microsoft .NET Framework 4.5.1 not installed!

:: Check for administrative access
:: This command will generate an error if privileges are not elevated

net session >nul 2>&1
echo.
if %errorLevel% == 0 (
  echo Administrative permissions confirmed.
) else (
  echo Current permissions inadequate
  echo ArcGIS Pro install failed
  goto :eof
)


:: Set log file path, prefix at install script runtime
:: Example LOG_PATH result: "%LOGDIR%\ArcGISPro_20120925_1623"
:: (%LOGDIR% is set above)

set DATESTAMP=%DATE:~10,4%%DATE:~4,2%%DATE:~7,2%
set TIMESTAMP=%TIME:~,2%%TIME:~3,2%
set TIMESTAMP=%TIMESTAMP: =0%
set LOG_PATH=%LOGDIR%\ArcGISPro_%DATESTAMP%_%TIMESTAMP%
set SILENT=/qb- /passive /norestart

:: Installation starts here


@echo on

:: Install ArcGIS Pro for all users of this computer
msiexec /i "%SRC%\Esri\ArcGISPro\ArcGISPro.msi"  ALLUSERS=1 INSTALLDIR=%INSTALLDIR%^

  /l+ie "%LOG_PATH%_Pro.txt" /l+ie "%LOG_PATH%.txt"  %SILENT%'
:: If you are installing 1.1, you can do the 1.1.1 .msp update at install time by putting
:: the patch file (.msp) in the same folder, like this:
::   msiexec /i "%SRC%\Esri\ArcGISPro\ArcGISPro.msi"  ALLUSERS=1 INSTALLDIR=%INSTALLDIR%^

::     PATCH="%SRC%\Esri\ArcGISPro\ArcGIS_Pro_111_147977.msp"^


::     /l+ie "%LOG_PATH%_Pro.txt" /l+ie "%LOG_PATH%.txt"  %SILENT%


:: ArcGIS Pro Help (optional local install [web help is also available])
msiexec /i "%SRC%\Esri\ArcGISProHelp\ArcGISProHelp.msi" ^
  /l+ie "%LOG_PATH%_Help.txt" %SILENT%
:: ArcGIS Pro Python 3.4 Stack - needed to run custom Python scripts
msiexec /i "%SRC%\Esri\ArcGISProPython\Python34.msi" ^
  /l+ie "%LOG_PATH%_Python.txt" %SILENT%

:: Optional: Set registry key to block ArcGIS Pro update prompts
%WINDIR%\system32\reg.exe add HKLM\SOFTWARE\ESRI\ArcGISPro\Settings ^
  /v CheckForUpdatesAtStartup /t REG_DWORD /d 0 /f

Attachments

    Outcomes